“These equations for tube characteristics are phenomenological equations, that is, equations that model the behaviour of physical phenomena using a reasonable number of parameters, but are not derived from fundamental physics.” – Norman Koren
Koren then goes on to explain that the models are based on the following
two expressions:
E1=(Vpk/Kp)*Log(1+exp(Kp((1/m)+Vgk/(sqrt(Kvb+Vpk^2)))
Ip=((E1^Ex)/Kg1)*(1+sgn(E1))
Sign function prevents current flow when E1 < 0
(many models do not account for this).
Shown below are Berkeley SPICE models for the 12AT7 & 12AX7.
If you wish to use them then copy & paste them into your component models
in Electronics Workbench 'Multisim'.
.SUBCKT 12AT7; a g k h hct
* MU=60 EX=1.35 KG1=460 KP=300 KVB=300 RGI=2000
* CCG=2.3P CGP=2.2P CCP=1.0P ; ADD .7PF TO ADJACENT PINS; .5 TO OTHERS.
B0 7 0 V=V(a,k)/300*LOG(1+EXP(300*(1/60+V(g,k)/SQRT(300+V(a,k)^2))))
RE1 7 0 1G
B1 a k I=((V(7,0)^1.35)/460)*(1+SGN(V(7,0)))
RCP a k 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 g k 2.3P ; CATHODE-GRID; WAS 1.6P
C2 g a 2.2P ; GRID-PLATE; WAS 1.5P
C3 a k 1.0P ; CATHODE-PLATE; WAS 0.5P
D3 5 k DX ; FOR GRID CURRENT
R1 g 5 2000 ; FOR GRID CURRENT
Rh h hct 40 ; HEATER RESISTANCE
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
.SUBCKT 12AX7; a g k h hct
* MU=100 EX=1.4 KG1=1060 KP=600 KVB=300 RGI=2000
* CCG=2.3P CGP=2.4P CCP=.9P ; ADD .7PF TO ADJACENT PINS; .5 TO OTHERS.
B0 7 0 V=V(a,k)/600*LOG(1+EXP(600*(1/100+V(g,k)/SQRT(300+V(a,k)^2))))
RE1 7 0 1G
B1 a k I=((V(7,0)^1.4)/1060)*(1+SGN(V(7,0)))
RCP a k 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 g k 2.3P ; CATHODE-GRID
C2 g a 2.4P ; GRID=PLATE
C3 a k 0.9P ; CATHODE-PLATE
D3 5 k DX ; FOR GRID CURRENT
R1 g 5 2000 ; FOR GRID CURRENT
Rh h hct 40 ; HEATER RESISTANCE
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
